参考文献网站开发/自媒体推广渠道

引言：

C#

任意测量平面进行测量

这个实验是把标定板置于任意方向及倾斜角度下(当然是在相机的景深范围内)，测量两点距离。

演示代码：*如果没标定先进行标定

*calib()

*磁盘载入标定结果

read_calib_data('D:/交流群的问题/skcircle1589_3d相机标定(三)/calib.ccd', CalibDataID)

*进行标定

calibrate_cameras(CalibDataID, Error)

*取得相机内参

get_calib_data (CalibDataID, 'camera', 0, 'params', CameraParameters)

stop ()

* open_framegrabber ('GigEVision2', 0, 0, 0, 0, 0, 0, 'progressive', \

-1, 'default', -1, 'false', 'default', '94aab8029638_Microvision_MVEM500M', 0, -1, AcqHandle)

* Image Acquisition 01: Code generated by Image Acquisition 01

list_files ('D:/交流群的问题/skcircle1589_3d相机标定(三)/', ['files','follow_links'], ImageFiles)

tuple_regexp_select (ImageFiles, ['\\.(tif|tiff|gif|bmp|jpg|jpeg|jp2|png|pcx|pgm|ppm|pbm|xwd|ima|hobj)$','ignore_case'], ImageFiles)

for i:=0 to |ImageFiles| - 1 by 1

read_image (Image, ImageFiles[i])

*grab_image(Image, AcqHandle)

dev_get_window(WindowHandle)

*write_image(Image, 'tiff', 0, 'D:/交流群的问题/skcircle1589_3d相机标定(三)/img4.tif')

TmpCtrl_PlateDescription := 'E:/Program Files/MVTec/HALCON-19.11-Progress/calib/calplateHG30.cpd'

TmpCtrl_FindCalObjParNames := 'sigma'

TmpCtrl_FindCalObjParValues := 1

*取当前标定板的位姿

create_calib_data ('calibration_object', 1, 1, CalibHandle)

set_calib_data_cam_param (CalibHandle, 0, [], CameraParameters)

set_calib_data_calib_object (CalibHandle, 0, TmpCtrl_PlateDescription)

find_calib_object (Image, CalibHandle, 0, 0, 0, TmpCtrl_FindCalObjParNames, TmpCtrl_FindCalObjParValues)

get_calib_data_observ_points (CalibHandle, 0, 0, 0, TmpCtrl_MarkRows, TmpCtrl_MarkColumns, TmpCtrl_Ind, CameraPose)

*设置原点位置

set_origin_pose (CameraPose, 0.0, 0.0,0, CameraPose)

startInx:=0

endInx:=13

dev_display(Image)

dev_set_draw('margin')

disp_circle(WindowHandle, TmpCtrl_MarkRows[startInx], TmpCtrl_MarkColumns[startInx], 64)

disp_circle(WindowHandle, TmpCtrl_MarkRows[endInx], TmpCtrl_MarkColumns[endInx], 64)

*可以看到这个是像素的距离

distance_pp(TmpCtrl_MarkRows[startInx], TmpCtrl_MarkColumns[startInx],\

TmpCtrl_MarkRows[endInx], TmpCtrl_MarkColumns[endInx], Distance)

*像素点映射为世界坐标上的点

image_points_to_world_plane(CameraParameters, CameraPose, \

TmpCtrl_MarkRows[startInx], TmpCtrl_MarkColumns[startInx], 'mm', X1, Y1)

image_points_to_world_plane(CameraParameters, CameraPose, \

TmpCtrl_MarkRows[endInx], TmpCtrl_MarkColumns[endInx], 'mm', X2, Y2)

distance_pp(X1, Y1, X2, Y2, Distance2)

dev_disp_text(''+Distance2, 'window', 50, 50, 'red', [], [])

*显示3D坐标轴

disp_3d_coord_system(WindowHandle, CameraParameters, CameraPose, 0.02)

stop ()

endfor

*close_framegrabber (AcqHandle)

read_calib_data 磁盘读入标定数据后要进行calibrate_cameras标定一次，这个别忘记了。

“取当前标定板的位姿”这一步过后，我们将以标定板的平面做为测量平面。

注意在测量的时候，只有标定板圆点范围内是能保证计算准确的，这也是为什么蜂窝标定板最好大小超出视野范围。

设定原点位置，这个Z传入是0，即相当于标定板为0厚度，因为我们取标定板表面做为测量平面，因此需要如此。

或者把下面这句注释掉也是可以的。set_origin_pose (CameraPose, 0.0, 0.0,0, CameraPose)

image_points_to_world_plane  将图像点转换为世界坐标系的平面z = 0(即测量平面)，可以白话为像素转世界坐标。

勇哥这块标定板圆点间距是2mm。

而且请注意勇哥这块标定板在不同的姿式下倾斜角度是随手摆的，并不是平放的。

由结果看来，精度是相当的高。

详细还可以参看勇哥录制的视频教程。

其它参考：

halcon例程： 3d_coordinates.hdev

这个例子想表现的知识点和勇哥上面讲的是一致。

只是，有个比较有意思的地方是，这个例子中标定板已经倾斜到45度了(这也是halcon推荐的)，怎么这个相机能有这么大的景深？

程序：*

* Initialize the program

dev_close_window ()

dev_open_window (0, 0, 768, 576, 'black', WindowHandle)

dev_update_off ()

dev_set_draw ('margin')

dev_set_line_width (3)

set_display_font (WindowHandle, 14, 'mono', 'true', 'false')

*

* Calibrate the camera

*

CalTabDescrFile := 'caltab_big.descr'

gen_cam_par_area_scan_division (0.008, 0, 0.0000086, 0.0000086, 384, 288, 768, 576, StartCamPar)

create_calib_data ('calibration_object', 1, 1, CalibDataID)

set_calib_data_cam_param (CalibDataID, 0, [], StartCamPar)

set_calib_data_calib_object (CalibDataID, 0, CalTabDescrFile)

NumImages := 10

for I := 1 to NumImages by 1

read_image (Image, 'calib/calib-3d-coord-' + I$'02d')

dev_display (Image)

Message := 'Find calibration plate in\nall calibration images (' + I + '/' + NumImages + ')'

disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')

* Find the calibration plate

find_calib_object (Image, CalibDataID, 0, 0, I - 1, [], [])

get_calib_data (CalibDataID, 'camera', 0, 'init_params', StartCamPar)

get_calib_data_observ_points (CalibDataID, 0, 0, I - 1, Row, Column, Index, Pose)

get_calib_data_observ_contours (Contours, CalibDataID, 'caltab', 0, 0, I - 1)

gen_cross_contour_xld (Cross, Row, Column, 6, 0.785398)

dev_set_color ('green')

dev_display (Contours)

dev_set_color ('yellow')

dev_display (Cross)

endfor

disp_continue_message (WindowHandle, 'black', 'true')

stop ()

calibrate_cameras (CalibDataID, Error)

get_calib_data (CalibDataID, 'camera', 0, 'params', CamParam)

*

* Perform measurements

*

for I := 1 to NumImages by 1

read_image (Image, 'calib/calib-3d-coord-' + I$'02d')

*

* Now, measure the size of the black border of the plate

get_measure_positions (Image, PlateRegion, CalibDataID, I, Distance, Phi, RowCenter, ColumnCenter)

gen_rectangle2_contour_xld (Rectangle, RowCenter, ColumnCenter, Phi, Distance * 0.52, 8)

gen_measure_rectangle2 (RowCenter, ColumnCenter, Phi, Distance * 0.52, 8, 768, 576, 'nearest_neighbor', MeasureHandle)

*

measure_pos (Image, MeasureHandle, 1, 40, 'all', 'all', RowEdge, ColumnEdge, Amplitude, Distance1)

Rows := [RowEdge[0],RowEdge[|RowEdge| - 1]]

Columns := [ColumnEdge[0],ColumnEdge[|RowEdge| - 1]]

gen_cross_contour_xld (Cross, Rows, Columns, 16, Phi)

*

* Transform the two border points into the world coordinate system

get_calib_data (CalibDataID, 'calib_obj_pose', [0,I - 1], 'pose', Pose)

image_points_to_world_plane (CamParam, Pose, Rows, Columns, 'm', SX, SY)

distance_pp (SY[0], SX[0], SY[1], SX[1], Width)

*

* Display results of width measurement

dev_display (Image)

dev_set_color ('white')

dev_set_line_width (3)

dev_display (Rectangle)

dev_set_color ('green')

dev_set_draw ('fill')

dev_set_line_width (2)

dev_display (Cross)

dev_set_draw ('margin')

disp_message (WindowHandle, 'Width = ' + (Width * 100)$'8.3f' + 'cm', 'window', 12, 12, 'black', 'true')

disp_continue_message (WindowHandle, 'black', 'true')

stop ()

*

* Now, measure the size of the calibration marks

*

* Extract the ellipses in the image

erosion_circle (PlateRegion, ROI, 17.5)

reduce_domain (Image, ROI, ImageReduced)

edges_sub_pix (ImageReduced, Edges, 'canny', 1, 20, 60)

select_contours_xld (Edges, SelectedEdges, 'contour_length', 20, 99999999, -0.5, 0.5)

* Fit ellipses to extracted edges

fit_ellipse_contour_xld (SelectedEdges, 'fitzgibbon', -1, 2, 0, 200, 3, 2, Row, Column, Phi, Radius1, Radius2, StartPhi, EndPhi, PointOrder)

MeanRadius1 := mean(Radius1)

MeanRadius2 := mean(Radius2)

DevRadius1 := deviation(Radius1)

DevRadius2 := deviation(Radius2)

* Transform the ellipses to world coordinates, where they should be circles

* and convert the circles from meters to millimeters so that we can see them.

contour_to_world_plane_xld (SelectedEdges, WorldCircles, CamParam, Pose, 'mm')

* Fit ellipses to the circles in world coordinates

fit_ellipse_contour_xld (WorldCircles, 'fitzgibbon', -1, 2, 0, 200, 3, 2, Row, Column, Phi, RadiusW1, RadiusW2, StartPhi, EndPhi, PointOrder)

MeanRadiusW1 := mean(RadiusW1)

MeanRadiusW2 := mean(RadiusW2)

DevRadiusW1 := deviation(RadiusW1)

DevRadiusW2 := deviation(RadiusW2)

*

* Display results of ellipse measurement

dev_display (Image)

dev_set_color ('yellow')

dev_set_line_width (3)

dev_display (SelectedEdges)

Message := 'Measured dimensions of the ellipses'

Message[0] := '                    Mean Radius1; Mean Radius2; (Standard deviations [%])'

Message[1] := 'Image coordinates:       ' + MeanRadius1$'5.2f' + 'px; ' + MeanRadius2$'5.2f' + 'px            (' + (DevRadius1 / MeanRadius1 * 100)$'4.2f' + ', ' + (DevRadius2 / MeanRadius2 * 100)$'4.2f' + ')'

Message[2] := 'World coordinates:       ' + (MeanRadiusW1 / 10)$'5.2f' + 'cm; ' + (MeanRadiusW2 / 10)$'5.2f' + 'cm            (' + (DevRadiusW1 / MeanRadiusW1 * 100)$'4.2f' + ', ' + (DevRadiusW2 / MeanRadiusW2 * 100)$'4.2f' + ')'

disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')

if (I 

disp_continue_message (WindowHandle, 'black', 'true')

stop ()

endif

endfor

get_measure_positions自定义函数的参数。

get_measure_positions的代码* Extract the calibration plate

threshold (Image, Region, 0, 120)

connection (Region, ConnectedRegions)

select_shape (ConnectedRegions, SelectedRegions, ['holes_num','rect2_len1','rect2_len2'], 'and', [1,120,120], [1,200,200])

fill_up (SelectedRegions, PlateRegion)

* Construct the measurement rectangle from the border of the table.

gen_contour_region_xld (PlateRegion, Contours, 'center')

segment_contours_xld (Contours, ContoursSplit, 'lines', 7, 4, 2)

regress_contours_xld (ContoursSplit, RegressContours, 'no', 1)

select_contours_xld (RegressContours, VerticalContours, 'direction', rad(45), rad(135), -0.5, 0.5)

select_contours_xld (VerticalContours, LongContours, 'length', 150, 500, -0.5, 0.5)

* The measurement line is constructed from the center points of the

* two vertical border lines of the table.

select_obj (LongContours, Contour, 1)

get_contour_xld (Contour, Rows, Columns)

RowBegin1 := Rows[0]

ColBegin1 := Columns[0]

RowEnd1 := Rows[|Rows| - 1]

ColEnd1 := Columns[|Columns| - 1]

select_obj (LongContours, Contour, 2)

get_contour_xld (Contour, Rows, Columns)

RowBegin2 := Rows[0]

ColBegin2 := Columns[0]

RowEnd2 := Rows[|Rows| - 1]

ColEnd2 := Columns[|Columns| - 1]

* Now do the actual measurement in the image

get_calib_data_observ_points (CalibDataID, 0, 0, PoseIndex - 1, Row, Column, PoseIndex, _Pose)

Row1 := Row[find(PoseIndex,21)]

Row2 := Row[find(PoseIndex,27)]

Column1 := Column[find(PoseIndex,21)]

Column2 := Column[find(PoseIndex,27)]

intersection_lines (Row1, Column1, Row2, Column2, RowBegin1, ColBegin1, RowEnd1, ColEnd1, RowA, ColA, IsOverlapping)

intersection_lines (Row1, Column1, Row2, Column2, RowBegin2, ColBegin2, RowEnd2, ColEnd2, RowB, ColB, IsOverlapping)

distance_pp (RowA, ColA, RowB, ColB, Distance)

line_orientation (RowA, ColA, RowB, ColB, Phi)

RowCenter := (RowA + RowB) / 2

ColumnCenter := (ColA + ColB) / 2

return ()

---------------------

作者：hackpig

来源：www.skcircle.com

版权声明：本文为博主原创文章，转载请附上博文链接！

#转载请注明出处 www.skcircle.com 《少有人走的路》勇哥的工业自动化技术网站。如果需要本贴图片源码等资源，请向勇哥索取。